This is a pretty simple script which puts all the /names and /who replies from the server into custom windows. This makes the data easy to find, as well as the fact that this script sorts the identifiers into a logical order before putting them into the window.
I just realised.. This is the first time I put custom windows into a script..
This needs to be put into your remotes tab (alt+r) under a new file (File->New).
EDIT: Forgot to make/delete the menu when it's used.
alias -l writewhonamesmenu {
write -c Popup_Who_Names.txt Clear Window: clear $chr(36) $+ active
write Popup_Who_Names.txt -
write Popup_Who_Names.txt Close Window: window -c $chr(36) $+ active
}
alias modnameson {
.enable #rawnames
writewhonamesmenu
echo -a Modified /NAMES activated.
}
alias modnamesoff {
.disable #rawnames
if ($group(#rawnames).status == off) && ($group(#rawwho).status == off) .remove Popup_Who_Names.txt
echo -a Modified /NAMES deactivated.
}
alias modwhoon {
.enable #rawwho
writewhonamesmenu
echo -a Modified /WHO activated.
}
alias modwhooff {
.disable #rawwho
if ($group(#rawnames).status == off) && ($group(#rawwho).status == off) .remove Popup_Who_Names.txt
echo -a Modified /WHO deactivated.
}
#rawnames on
raw 353:*: {
if (!$window(/names)) window -ik0n1z @/names Popup_Who_Names.txt
if (!$fline(@/names,*script made by Gummo*,1)) aline -hp 4 @/names Raw /NAMES script made by Gummo
aline -hp @/names $3 $+ : $4-
halt
}
raw 366:*: {
if (!$window(/names)) window -ik0n1z @/names Popup_Who_Names.txt
aline -hp @/names $2 $+ : End of /NAMES list.
aline -hp @/names -
echo -a $chan $+ : End of /NAMES list.
halt
}
#rawnames end
#rawwho on
raw 352:*: {
if (!$window(/who)) window -ik0n1z @/who Popup_Who_Names.txt
if (!$fline(@/who,*script made by Gummo*,1)) aline -hp 4 @/who Raw /WHO script made by Gummo
aline -hp @/who $+($2,: $6,!,$3,@,$4) * Realname: $9 * Server: $5
halt
}
raw 315:*: {
if (!$window(/who)) window -ik0n1z @/who Popup_Who_Names.txt
aline -hp @/who $2 $+ : End of /WHO list.
aline -hp @/who -
echo -a $2 $+ : End of /WHO list.
halt
}
#rawwho end