just a dialog to get a Master Key to reset the parental control password on the Wii.
Copy/paste into a new remote click either on ur menubar or in a channel to open.
get the 8 digit Confirmation Number off of the Wii,
and type it in the edit box then click get key
[size=15]Feel free to rip butcher or strip this code how ever you want I Don't Care.[/size]
dialog wii {
title "Wii Password Reset"
size -1 -1 107 46
option dbu
text "Confirmation Number:", 1, 4 10 53 8
edit "", 2, 59 10 44 9, autohs
box "Functions", 5, 2 2 103 42
text "Master Key:", 3, 4 20 31 8
edit "", 4, 59 20 44 9, center read
button "Clipboard", 6, 4 32 33 10, flat
button "Get Key", 7, 37 32 33 10, flat
button "Close", 8, 70 32 33 10, flat cancel
}
menu menubar,channel {
.Wii Password Reset:{ dialog $iif($dialog(wii),-v,-md wii) wii }
}
on *:dialog:wii:init:0:{ did -b $dname 6,7 }
on *:dialog:wii:edit:2:{
noop $regex($did(2).text,/^(\d+)$/)
did $iif($len($regml(1)) = 8,-e,-b) $dname 7
if ($did(2).text !isnum) {
noop $input(Enter Numbers Only,udho,Error!)
did -r $dname 2,4
did -b $dname 6,7
}
}
on *:dialog:wii:sclick:*:{
if ($did == 7) {
if ($sock(wii)) .sockclose wii
sockopen wii wii.marcansoft.com 80
sockmark wii $+(/parental.wsgi?number=,$did(2).text,&date=,$date(mmdd),&submit=Get+Reset+Code)
}
if ($did == 6) { clipboard $did(4).text }
}
on *:sockopen:wii: {
sockwrite -nt wii GET $sock(wii).mark HTTP/1.1
sockwrite -nt wii Host: $+($sock(wii).addr,$str($crlf,2))
}
on *:sockread:wii: {
var %wii | sockread %wii
if ($regex(%wii,/<span class="code">(\d+?)<\/span>/)) {
did -ra wii 4 $regml(1)
did -e wii 6
sockclose wii
}
}
Great snippet.
For your records, it gets the key from a website that you can use if do not want to use code:
http://wii.marcansoft.com/parental.psp
not that hard to understand.
say you forgot what the parental control password is on ur wii.
all you have to do is go into the parental control options an get the 8 digit Confirmation Number then type the Confirmation Number in the edit box as i said in the intro to get a master key to reset the password.